Academic Company Events NI Developer Zone Support Solutions Products & Services Contact NI MyNI
This Document is not yet Rated  Rate this Document

在NI-RFSG1.2中使用脚本触发时某些特殊的脚本触发会引起错误。

主要软件: Driver Software>>NI-RFSG
主要软件版本: N/A
主要软件修正版本: N/A
次要软件: N/A
硬件: Modular Instruments>>RF Measurement Devices>>PXI-5660, Modular Instruments>>RF Measurement Devices>>PXI-5600, Modular Instruments>>RF Measurement Devices>>PXI-5610, Modular Instruments>>RF Measurement Devices>>PXI-5671

问题:
为什么在"repeat Forever"中嵌套"repeat until scriptTriggerX"，会出现异常？

解答:
在NI-RFSG1.2中引入的脚本语言用于信号发生器设备是一种非常灵活的技术，有很少的几条脚本语句不能正常工作，这些脚本语句包括：在“repeat Forever” 结构中嵌套“repeat until scriptTriggerX”，例如，下面的脚本就不能正常运行：

script myScript0
repeat Forever
repeat until scriptTrigger0
generate wfmSine
end repeat
generate wfmSquare
end repeat
end script

这段脚本的原本意图是，任意波发生器不断循环的生成正弦波，当scriptTrigger0来到的时候，开始发生方波，如果scriptTrigger再次触发，就重新生成正弦波。然而，不幸的是，当收到第一次scriptTrigger0，生成一次方波，然后就自动循环生成正弦波， 当scriptTrigger 第二次触发时，信号发生就停止了。 要解决这个问题，需要在脚本中再添加一个scriptTrigger。

配置另一个scriptTriggerX (例如scriptTrigger 1)数字电平触发使用 niRFSG Configure Script Trigger Digital Edge.vi。配置有效电平为上升沿，触发源为“PFI 0”。配置方法参考下面的例子。

LabVIEW Code Portion

另外再加一个 “generate wfmSquare”指令在“repeat until scriptTriggerX”中， 具体的改法参考下面的例子：

script myScript0Fixed
  repeat Forever
    repeat until scriptTrigger0
      generate wfmSine
    end repeat
    repeat until scriptTrigger1
      generate wfmSquare
    end repeat
  end repeat
end script

尽管“generate wfmSquare”语句在“repeat until..”结构中，scriptTrigger还是可以被置为有效的。

下面是一些类似的有问题的脚本触发的例子，请参考，右边是改正后的版本。

IssueFixed Version
script myScript1
  generate wfmSquare
  repeat Forever
    repeat until scriptTrigger0
      generate wfmSine
    end repeat
 end repeat
end script		script myScript1Fixed
  repeat until scriptTrigger1
    generate wfmSquare
  end repeat
  repeat Forever
    repeat until scriptTrigger0
      generate wfmSine
    end repeat
  end repeat
end script

这是另一个例子，如下所示：

IssueFixed Version
script myScript2
  wait until scriptTrigger0
  repeat Forever
    repeat until scriptTrigger0
      generate wfmSine
    end repeat
  end repeat
end script		script myScript2Fixed
  repeat until scriptTrigger0
    generate wfmZeroes
  end repeat
  repeat Forever
    repeat until scriptTrigger0
      generate wfmSine
    end repeat
  end repeat
end script


相关链接:
Drivers and Updates: RF Measurement Hardware

附件:


rfsg_example.JPG

报告日期: 06/30/2006
最近更新: 06/29/2006
文档编号: 3WPGQ3G4

Your Feedback! poor Poor  |  Excellent excellent   Yes No
 Document Quality? 
 Answered Your Question? 
  1 2 3 4 5
Please Contact NI for all product and support inquiries.submit